1 files changed, 41 insertions, 0 deletions
diff --git a/st/PKGBUILD b/st/PKGBUILD
new file mode 100644
index 0000000..33efc08
--- /dev/null
+++ b/st/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Tharre <tharre3@gmail.com>
+
+pkgname=st
+pkgver=0.6.r31.g5d2d9d5
+pkgrel=1
+pkgdesc='Simple virtual terminal emulator for X'
+url='http://git.suckless.org/st/'
+arch=('i686' 'x86_64' 'armv7h')
+license=('MIT')
+depends=('libxft')
+makedepends=('ncurses' 'libxext' 'git')
+source=('st::git+https://github.com/Tharre/st-transparency.git#branch=custom_config'
+        'st-terminal.desktop')
+md5sums=('SKIP'
+         'bbe3714218145d39b6920961f27692e6')
+
+provides=("${pkgname}")
+conflicts=("${pkgname}")
+
+pkgver() {
+	cd "${srcdir}/${pkgname}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "${srcdir}/${pkgname}"
+	ln -sf config.def.h config.h
+}
+
+build() {
+	cd "${srcdir}/${pkgname}"
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+	make PREFIX=/usr DESTDIR="${pkgdir}" TERMINFO="${pkgdir}/usr/share/terminfo" install
+	install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+	install -Dm644 README FAQ -t "${pkgdir}/usr/share/doc/${pkgname}"
+	install -Dm644 "${srcdir}/st-terminal.desktop" -t "${pkgdir}/usr/share/applications"
+}