From 9ac120ef7ac5914556e7922bf579ebfa6ed77ea0 Mon Sep 17 00:00:00 2001
From: Tharre <tharre3@gmail.com>
Date: Thu, 19 Mar 2015 22:28:57 +0100
Subject: Add a custom, patched version of st as st-custom

---
 st-custom/PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 st-custom/PKGBUILD

(limited to 'st-custom/PKGBUILD')

diff --git a/st-custom/PKGBUILD b/st-custom/PKGBUILD
new file mode 100644
index 0000000..254dc39
--- /dev/null
+++ b/st-custom/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Tharre <tharre3@gmail.com>
+
+pkgname=st-custom
+_pkgname=st
+pkgver=0.5.r168.gc9357a8
+pkgrel=1
+pkgdesc='Simple virtual terminal emulator for X'
+url='http://git.suckless.org/st/'
+arch=('i686' 'x86_64' 'armv7h')
+license=('MIT')
+depends=('libxft')
+makedepends=('ncurses' 'libxext' 'git')
+source=('git://git.suckless.org/st' 'config.h' 'st-terminal.desktop' 'transparency.diff')
+md5sums=('SKIP'
+         '3479bef061e1b22e30624caa44fdcfa8'
+         'bbe3714218145d39b6920961f27692e6'
+         '97e7829670ad6aff4e57e611390c753a')
+
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+
+pkgver() {
+	cd "${srcdir}/${_pkgname}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	cd "${srcdir}/${_pkgname}"
+	patch < ../transparency.diff
+	ln "${srcdir}/config.h" config.h
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}"
+	make
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}"
+	make PREFIX=/usr DESTDIR="${pkgdir}" TERMINFO="${pkgdir}/usr/share/terminfo" install
+	install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+	install -Dm644 README FAQ -t "${pkgdir}/usr/share/doc/${pkgname}"
+	install -Dm644 "${srcdir}/st-terminal.desktop" -t "${pkgdir}/usr/share/applications"
+}
-- 
cgit v1.2.3-70-g09d2