blob: 70ab2b35c16213d879beb1bf5b03a1ace5e4caf6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Tharre <tharre3@gmail.com>
pkgname=st-custom
_pkgname=st
pkgver=0.7.r3.gde3760b
pkgrel=1
pkgdesc='Simple virtual terminal emulator for X'
url='http://git.suckless.org/st/'
arch=('i686' 'x86_64' 'armv7h')
license=('MIT')
depends=('libxft' 'adobe-source-code-pro-fonts' 'ttf-dejavu')
makedepends=('ncurses' 'libxext' 'git')
source=('st::git+https://github.com/Tharre/st-transparency.git#branch=custom_config'
'st-terminal.desktop')
md5sums=('SKIP'
'bbe3714218145d39b6920961f27692e6')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgname}"
ln -sf config.def.h config.h
}
build() {
cd "${srcdir}/${_pkgname}"
make
}
package() {
cd "${srcdir}/${_pkgname}"
make PREFIX=/usr DESTDIR="${pkgdir}" install
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm644 README FAQ -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm644 "${srcdir}/st-terminal.desktop" -t "${pkgdir}/usr/share/applications"
}
|
